REM ----------------------------------------------
REM SRTM3を用いた地形図作成サンプル　　　20090106
REM ----------------------------------------------

rem ----set文で設定される変数----------------------------------------
rem set文の＝の左の変数名は、スクリプト中で%で挟まれた形式で参照される。
rem set文の＝の右はパスを含めたファイル名、文字列を含んだ数値などが設定できる。

rem ----変数の説明----
rem of:GMTで描画するポストスクリプトファイル名
rem cp:デフォルトのカラーパレットデータ
rem cpt:描画領域の標高に適合されたカラーパレットデータ
rem waku: 描画領域（西端経度、東端経度、南端緯度、北端緯度）
rem grddata：GMTグリッドに変換済のSRTM3グリッド(srtm_65_04.zip)
rem city: 市名データ（市名、市役所緯度経度）国土地理院WEBサイトより入手したデータを利用
rem town: 町名データ（町名、町役場緯度経度）　　　　　　　　　同上
rem vill: 村名データ（村名、村役場緯度経度）　　　　　　　　　同上
rem mount: 山岳データ（山名、山頂緯度経度）　　　　　　　　　 同上
rem hokriv: 北海道の河道網データ
rem bp: a：軸目盛数字の間隔（度）、b:白黒帯の間隔（度）、g：線の間隔（度）。分のときは*.*m、秒のときは*.*c
rem r: １度あたりの描画長（ここではcm）

rem ----set文による変数の設定----
set of=daisetsu.ps
set cp=GMT_globe.cpt
set cpt=GMT_hok.cpt
set waku=142/144/43/44
set grddata=..\topodata\srtm6504.grd
set city=hok_bc_ll.euc
set town=hok_tn_ll.euc
set vill=hok_vl_ll.euc
set mount=h_m_ltln.euc
set hokriv=hokkaido.riv
set bp=a0.5f0.25g0.0
set r=8

rem ----GMTコマンドの説明----
rem makecptコマンド：カラーパレットを標高範囲で調整。-Zは無段階でパレットが変化。
rem grdgradientコマンド：DEMデータから陰影イメージを作成　
rem grdimage：DEMグリッドを描画し、陰影イメージを付加
rem gawk： awkと呼ばれるUNIX系のコマンドの一種.同じパターンのデータ並びから特定の
rem 順番でデータを取り出すことができる。ここではパイプコマンド|により、psxyやpstext
rem にデータを渡している。↓使用例
rem gawk "{print $4,$3}" %hokriv% | psxy では、%hokriv%の4列目($4) と3列目($3)のデータを
rem パイプコマンド｜でpsxyに渡している。
rem pscoast:海岸線だけでなく、設定によっては国境や河川も描画でき、-S255　を指定すると
rem 描画領域の外を白抜きできる。
rem -----

rem ----GMTコマンドの実行----
makecpt -CGMT_globe.cpt -T-2300/2300/100 -Z > %cpt%
psbasemap -Jm%r% -R%waku% -B%bp% -P -K > %of%
grdgradient %grddata% -Gtbasegrad.grd -A45 -Ne0.4
grdimage %grddata% -Jm%r% -R%waku% -B%bp% -C%cpt% -Itbasegrad.grd -P -O -K >> %of%
gawk "{print $1,$2}" %hokriv% | psxy -Jm%r% -W1/0/0/255 -M -R -P -V -O -K >> %of%
pscoast -Jm%r% -R -B -W2 -Dh -P -V -S255 -O -K >> %of%
rem ----都市名、山岳名を漢字で描画(データは国土地理院WEBサイトで入手)----------------
gawk "{print $2,$3}" %city% | psxy -R%waku% -Jm%r% -Sc0.1 -W1/0/0/0 -G255/0/0 -O -K >> %of%
gawk "{print $2,$3,8,0,35,5,$1}" %city% | pstext -R%waku% -Jm%r% -O -K >> %of%
gawk "{print $2,$3}" %town% | psxy -R%waku% -Jm%r% -Sc0.075 -W1/0/0/0 -G255/0/0 -O -K >> %of%
gawk "{print $2,$3,6,0,35,5,$1}" %town% | pstext -R%waku% -Jm%r% -O -K >> %of%
gawk "{print $2,$3}" %vill% | psxy -R%waku% -Jm%r% -Sc0.075 -W1/0/0/0 -G255/0/0 -O -K >> %of%
gawk "{print $2,$3,6,0,35,5,$1}" %vill% | pstext -R%waku% -Jm%r% -O -K >> %of%
gawk "{print $4,$3}" %mount% | psxy -R%waku% -Jm%r% -St0.1 -W1/0/0/0 -G255/0/0 -O -K >> %of%
gawk "{print $4,$3,4,0,35,5,$1}" %mount% | pstext -R%waku% -Jm%r% -O -K >> %of%
rem ----標高スケールの描画-----------------------------------------------------------
psscale -D7/-1/10/0.3h -C%cpt% -Ba1000f500 -O >> %of%